@echo off
if A%1==AHD_Run goto :install
@echo * * * * *
@echo WARNING: THIS SHELL SCRIPT WILL INSTALL CCT ON THE CURRENT DRIVE!
@echo * * * * *
@echo This package combines emTeX-386 3.14159 [4a] and CCT's DVI
@echo drivers v5.13, which will be installed in the subdirectory "\EMTEX" on
@echo the current hard disk partition. If you are not logged on the hard disk
@echo partition on which you plan to install TeX and CCT, hit [Ctrl]+[Break]
@echo to exit and then restart the installation.
@echo * * * * *
@echo To install from drive B:, type:
@echo 	B:INSTALL B:
@echo To install from a subdirectory, say d:\toto, type:
@echo 	D:\TOTO\INSTALL D:\TOTO
pause

cd \ >nul
mkdir \emtex >nul
cd \emtex
if A%1==A goto :inst_a
if not exist %1\install.bat goto :not_found
copy %1\install.bat >nul
\emtex\install HD_Run %1
:inst_a
if not exist a:\install.bat goto :not_found
copy a:\install.bat >nul
\emtex\install HD_Run A:

:install
@echo off
@echo *
@echo Source path=%2
@echo *

@echo 	*
@echo 	* Making directories...
@echo 	*
cd \emtex
mkdir texinput >nul
mkdir tfm >nul
mkdir btexfmts >nul
mkdir doc >nul

copy %2\readme.cct doc >nul
copy %2\cctman.zip doc >nul
copy %2\unzip.exe >nul
copy %2\sample.ctx >nul

@echo 	*
@echo 	* Installing DVI drivers to the directory \EMTEX...
@echo 	*
rem Delete old files
del tiftobmf.exe >nul
del bmftotif.exe >nul
del pcl2bmf.exe >nul
\emtex\unzip -oaL %2\progs

\emtex\forall -s (cart??.sty cbk??.sty crep??.sty carticle.sty cbook.sty creport.sty cletter.sty) del %%f >nul
\emtex\forall -s (cchead.sty cctart.* cctbook.* ccfnt?.tfm ccdummy.tfm) del %%f >nul

@echo 	*
@echo 	* Installing emTeX programs to the directory \EMTEX...
@echo 	*
\emtex\unzip -oaL %2\emtex386
copy *.poo btexfmts\. >nul
del *.poo >nul
copy *.doc doc\. >nul
del *.doc >nul
del tex.exe >nul
ren tex386.exe tex.exe


if exist %2\TEX.2 goto disk2_ok
:askdisk2
@echo Please insert TeX3.14159 diskette #2/3 (tex-2) into drive %2
pause
if not exist %2\TEX.2 goto askdisk2
:disk2_ok

@echo 	*
@echo 	* Copying macro files to the directory \EMTEX\TEXINPUT...
@echo 	*
cd \emtex
\emtex\unzip -oaL %2\texinput

@echo 	*
@echo 	* Copying TFM files to the directory \EMTEX\TFM...
@echo 	*
cd \emtex
\emtex\unzip -oaL %2\tfm

@echo 	*
@echo 	* Copying MAKEINDEX programs and docs to \EMTEX...
@echo 	*
cd \emtex
\emtex\unzip -oaL %2\makeindx

@echo 	*
@echo 	* Generating FMT files...
@echo 	*
cd \emtex\btexfmts
SET EMTEXDIR=\EMTEX
rem SET TEXINPUT=\EMTEX\TEXINPUT!
rem SET BTEXFMT=\EMTEX\BTEXFMTS!
rem SET TEXTFM=\EMTEX\TFM!
SET EMX=\EMTEX\EMX.EXE
SET RSX=\EMTEX\RSX.EXE
\emtex\tex/i plain \dump
\emtex\tex/i latex.ltx \dump
\emtex\tex/i amstex.ini
del *.log >nul
del *.aux >nul
if not exist plain.fmt goto :fmterr
if not exist latex.fmt goto :fmterr
if not exist amstex.fmt goto :fmterr
goto :fmtok
:fmterr
@echo ************
@echo Unable to create .FMT files. Please rename the files "C:\CONFIG.SYS",
@echo and "C:\AUTOEXEC.BAT", reboot the computer, and then restart the
@echo installation.
goto :fin
:fmtok

\emtex\cctinit -H\emtex\texinput -T\emtex\tfm
@echo TeX programs and device drivers installed.
%2\setpath
call \emtex\setenv
cd\


if exist %2\TEX.3 goto disk3_ok
:askdisk3
@echo Please insert TeX3.14159 diskette #3/3 (tex-3) into drive %2
pause
if not exist %2\TEX.3 goto askdisk3
:disk3_ok

@echo 	*
@echo 	* Installing MF386...
@echo 	*
cd \
\emtex\unzip -oaL %2\mf386.zip


if exist %2\HZINST.EXE goto disk4_ok
:askdisk4
@echo If you don't want to install Chinese PPS fonts, press Ctrl-Break now,
@echo otherwise insert PPS fonts diskette #1/4 (hzfnts-1) into drive %2
pause
if not exist %2\HZINST.EXE goto askdisk4
:disk4_ok

%2\HZINST

@echo ****************************************************
@echo * CCT V5.13 successfully installed.
@echo *
@echo * Please add the following line:
@echo *
@echo * 	call <drive>:\emtex\setenv.bat
@echo *
@echo * to the file C:\AUTOEXEC.BAT.
@echo *
@echo * If you are running Windows 95/98/NT, please reboot
@echo * your computer before using CCT.
@echo ****************************************************

goto fin

:not_found
@echo Invalid source drive!

:fin
del \emtex\install.bat >nul